add: gpu antisag bracket

openscad/own/gpu-antisag/gpu-antisag.scad

@@ -0,0 +1,54 @@
+// by zeus - zeus@ctdo.de - CC-BY-NC-4.00
+// -> https://www.thingiverse.com/zeus
+// -> https://www.printables.com/social/366928-zeus/about
+// -> https://github.com/zeus86
+// -> https://blog.tastatursport.de/
+// 2023-03-28
+// GPU-antisag-adapter for O11D-Evo with vertical GPU Kit and 25mm Bottom-Fans (default orientation)
+//##################
+// 
+//
+//##################
+//
+// VARS
+mt=5;               // general material thickness
+cen_w=8;            // center bar
+cen_h=mt;           // center bar
+cen_elev=25;        // total center elevation
+depth=110;          // 110 for 120mm fans
+tri_w=40;           // triangular plate
+tri_x=tri_w/sqrt(2);// nominal side-length of the square-section, the triangular shape is made of
+tri_h=mt;           // triangular plate
+$fn=100;            // general resolution
+q=0.01;             // used to avoid graphical glitches
+hds=15;             // short hole-distance
+hdl=105;            // long hole distance
+holedia=4.5;        // diameter of the hole for the screw//
+//##################
+//
+// MODEL
+module triangle(){
+  difference(){
+      rotate([0,0,45])cube([tri_x,tri_x,mt],center=true);
+      translate([0,-tri_w/2,0])cube([tri_w,tri_w,5+q],center=true);
+      for (x=[hds/2,-hds/2]){
+          translate([x,holedia,0]){
+              cylinder(r=holedia/2,h=mt+q,center=true);
+              translate([0,0,holedia/2])cylinder(r1=holedia/2,r2=holedia,h=mt+q,center=true);
+          }
+      }
+  }  
+};
+
+module cen(){
+    hull(){
+        cube([cen_w,hdl-q,cen_h],center=true);
+        translate([0,0,cen_elev-mt])#cube([cen_w,hdl/2,cen_h],center=true);
+    }
+}
+
+translate([0,0,mt/2]){
+    triangle();
+    translate([0,hdl/2,0])cen();
+    translate([0,hdl,0])rotate([0,0,180])triangle();
+}